การใช้งาน NodeMCU ESP8266 ESP-12E Module

การจะใช้ NodeMCU ได้นั้น จำเป็นต้องติดตั้ง ESP8266 Platform เพื่อ ทำการติดต่อ ระหว่าง Arduino IDE กับ NodeMCU


ลิงค์ : ขั้นตอนการติดตั้ง ESP8266 Platform


https://robotsiam.blogspot.com/2017/06/esp8266-platform-nodemcu.html



จากนั้นทดสอบการทำงานของ NodeMCU ESP8266 ESP-12E Module


โดยใช้โปรเจค 
ควบคุม การ ปิด / เปิด LED จาก เว็บเบราเซอร์ โดยใช้ NodeMcu


โปรเจคนี้ จะควมคุมผ่าน ระบบ
อินทราเน็ต ที่ใช้ WIFI หรือ วง แลน หรือใช้ เราเตอร์ เดียวกัน เท่านั้น


เราจะเชื่อมต่อ ESP8266 ESP-12E กับเราเตอร์ WiFi โดยใช้ SSID หรือ ชื่อ WiFi ที่ต้องการเชื่อมต่อ และรหัสผ่าน ของเครือข่าย

ซึ่ง ESP8266 เมื่อเชื่อมต่อกับ WiFi ของเราแล้ว จะสร้างเว็บเซิร์ฟเวอร์ ซึ่งสามารถเข้าถึงได้โดยการมองผ่าน Serial Monitor ของ Arduino IDE และ ควบคุมผ่านทาง เว็บเบราเซอร์ ของคอมพิวเตอร์ ที่เชื่อมต่อ WiFi วงเดียวกัน


อุปกรณ์ที่ใช้  



1. 
NodeMCU V2 Lua WIFI  ESP8266 ESP-12E Module

2. Micro USB Cable Wire 1m for NodeMCU

3. Breadboard 8.5CM x 5.5CM 400 holes

4. หลอดไฟ LED





ต่อวงจรตามรูป




การเขียนโปรแกรม Arduino IDE กับ NodeMCU นั้น ต้องใช้การเทียบขาดังรูปด้านล่าง เช่นเมื่อต้องการให้ D7 ของ NodeMCU ทำงานต้องใช้ คำสั่งเป็น ขา 13






โค้ด 
ควบคุม การ ปิด / เปิด LED จาก เว็บเบราเซอร์ โดยใช้ NodeMcu


ก่อนการอัพโหลดต้องแก้ไขโค้ด ตรง = "xxxxx" ให้ถูกต้องโดย


ssid = "ชื่อwifiที่ต้องการเชื่อมต่อ"

password =  "รหัสผ่าน"




แล้วจึงอัพโหลดโค้ดที่แก้ไขแล้ว เข้าไปยัง NodeMCU 


#include <ESP8266WiFi.h>
const char* ssid = "xxxxx";
const char* password = "xxxxx";
int ledPin = 13; // GPIO13
WiFiServer server(80);
void setup() {
  Serial.begin(115200);
  delay(10);
  pinMode(ledPin, OUTPUT);
  digitalWrite(ledPin, LOW);
  // Connect to WiFi network
  Serial.println();
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");
  // Start the server
  server.begin();
  Serial.println("Server started");
  // Print the IP address
  Serial.print("Use this URL to connect: ");
  Serial.print("http://");
  Serial.print(WiFi.localIP());
  Serial.println("/");
}
void loop() {
  // Check if a client has connected
  WiFiClient client = server.available();
  if (!client) {
    return;
  }
  // Wait until the client sends some data
  Serial.println("new client");
  while(!client.available()){
    delay(1);
  }
  // Read the first line of the request
  String request = client.readStringUntil('\r');
  Serial.println(request);
  client.flush();
  // Match the request
  int value = LOW;
  if (request.indexOf("/LED=ON") != -1)  {
    digitalWrite(ledPin, HIGH);
    value = HIGH;
  }
  if (request.indexOf("/LED=OFF") != -1)  {
    digitalWrite(ledPin, LOW);
    value = LOW;
  }
// Set ledPin according to the request
//digitalWrite(ledPin, value);
  // Return the response
  client.println("HTTP/1.1 200 OK");
  client.println("Content-Type: text/html");
  client.println(""); //  do not forget this one
  client.println("<!DOCTYPE HTML>");
  client.println("<html>");
  client.print("Led pin is now: ");
  if(value == HIGH) {
    client.print("On");
  } else {
    client.print("Off");
  }
  client.println("<br><br>");
  client.println("<a href=\"/LED=ON\"\"><button>Turn On </button></a>");
  client.println("<a href=\"/LED=OFF\"\"><button>Turn Off </button></a><br />");  
  client.println("</html>");
  delay(1);
  Serial.println("Client disonnected");
  Serial.println("");
}


.....

การติดตั้ง ESP8266 Platform สำหรับ NodeMCU




การจะใช้ NodeMCU ได้นั้น จำเป็นต้องติดตั้ง ESP8266 Platform เพื่อ ทำการติดต่อ ระหว่าง Arduino IDE กับ NodeMCU


เริ่มโดย เปิด Arduino IDE ขึ้นมา


ไปที่ File -> Preferences



จากนั้น ไปที่ช่อง Additional Boards Manager URLs: ป้อน URL นี้

 
http://arduino.esp8266.com/stable/package_esp8266com_index.json

เข้าไป

จากนั้น คลิก OK





ไปที่ Tools ไปที่ Board:   คลิกที่ Boards Manager...




เลื่อนหา esp8266 by ESP8266 Community




คลิกที่ Online help จะ ปรากฏ ปุ่ม Install ขึ้นมา แล้วจึงคลิกที่  Install

เพื่อทำการติดตั้ง ESP8266 Platform




รอจนกระทั่งการติดตั้งเสร็จสมบูรณ์




ไปที่ Tools -> Board:

เลือนลงดู ด้านล่างสุด จะมี ESP8266 Platform เพิ่มเข้ามา



เพิ่มโค้ด

#include <ESP8266WiFi.h>


เข้าไปที่ ด้านบนสุดดังรูป



#include <ESP8266WiFi.h>

void setup() {
  // put your setup code here, to run once:

}

void loop() {
  // put your main code here, to run repeatedly:

}


เลือก Board : NodeMCU 1.0 (ESP-12E Module)




คลิกที่เครื่องหมายถูก เพื่อทดลอง คอมไพล์




ถ้าขึ้น Done compiling แสดงว่า Arduino IDE ของเรานั้นพร้อมใช้งานกับ NodeMCU แล้วครับ


การใช้งาน ESP8266 ESP-01 Wireless WIFI Module

การใช้งาน ESP8266 ESP-01 นั้น ตามสเปคต้องการใช้ไฟเลี้ยง 3.3V ฉะนั้นเพื่อความปลอดภัย ของ ESP8266 ESP-01 เราจึงต้องหาแหล่งจ่ายไฟ 3.3V

โดยการเชื่อมต่อจาก VCC (5V) ของ Arduino UNO ทำการลดแรงดันไฟให้เหลือ 3.3V โดยใช้ ไอซีเร็กกูเลเตอร์ LD1117  แล้วจึงต่อเข้ากับ VCC และ PH_PD ของ ESP8266 ESP-01 ดังรูป


การต่อวงจร
  • ESP-01 <--> UNO
  • VCC <--> 3.3V
  • GND<--> GND
  • CH_PD<-->3.3V
  • TX<-->D2
  • RX<-->D3


อุปกรณ์ที่ใช้


1. Arduino UNO R3 - Made in italy

2. ESP8266 ESP-01 Wireless WIFI Module

3. ไอซีเร็กกูเลเตอร์ LD1117

4. คาปาซิเตอร์ 100 nF

5. คาปาซิเตอร์ 10 uF

6. สาย Jumper Female to Male ยาว 20cm.

7. สาย Jumper Male to  Male ยาว 20cm.




การใช้งานเบื้องต้น



อัพโหลดโค้ด Arduino เพื่อให้ สื่อสารกับ  ESP8266 ESP-01 ได้


#include <SoftwareSerial.h>

SoftwareSerial esp8266(2,3); // make RX Arduino line is pin 2, make TX Arduino line is pin 3.
                             // This means that you need to connect the TX line from the esp to the Arduino's pin 2
                             // and the RX line from the esp to the Arduino's pin 3
void setup()
{
  Serial.begin(9600);
  esp8266.begin(9600); // your esp's baud rate might be different
}

void loop()
{
  if(esp8266.available()) // check if the esp is sending a message
  {
    while(esp8266.available())
    {
      // The esp has data so display its output to the serial window
      char c = esp8266.read(); // read the next character.
      Serial.write(c);
    }
  }


  if(Serial.available())
  {
    // the following delay is required because otherwise the arduino will read the first letter of the command but not the rest
    // In other words without the delay if you use AT+RST, for example, the Arduino will read the letter A send it, then read the rest and send it
    // but we want to send everything at the same time.
    delay(1000);
   
    String command="";
   
    while(Serial.available()) // read the command character by character
    {
        // read one character
      command+=(char)Serial.read();
    }
    esp8266.println(command); // send the read character to the esp8266
  }
}



เรียนรู้ชุดคำสั่ง AT



คำสั่ง AT  คือ ชุดคำสั่งมาตรฐาน ที่สามารถใช้ติดต่อสื่อสารกับอุปกรณ์สื่อสารต่างๆ เช่น โมเด็ม หรือ อุปกรณ์ DTE (Data Terminal Equipment) เพื่อโต้ตอบตั้งค่าหรือสั่งงานอุปกรณ์เหล่านั้น ให้ทำงานตามที่ต้องการ

เป้าหมายของโค้ดนี้ก็คือการรับคำสั่ง AT จากพอร์ต อนุกรม ของ Arduino เพื่อส่งไปยัง ESP8266 และพิมพ์คำตอบของ ESP8266 ไปยังคำสั่งหรือการกระทำอื่น ๆ (เช่นการรับคำขอ HTTP)

เปิด Serial Monitor ของ Arduino ตั้งค่า baud rate 9600 และปรับช่องในรูปให้เป็น ฺBoth NL&CR

พิมพ์ AT+RST หรือ พิมพ์ AT แล้วกด Send ถ้ามีคำว่า ready หรือการตอบสนอง แสดงว่าบอร์ดเรายังใช้งานได้อยู่ ไปทดสอบ Step ต่อไป


พิมพ์ AT+GMR เป็นคำสั่งเช็คเวอร์ชัน เมื่อพิมพ์แล้วจะได้ผลลัพธ์ของเวอร์ชัน Firmware ถ้า 0016091 เป็นเวอร์ชัน 0.91 ถ้า 0018000902 เป็นเวอร์ชัน 0.9.2.2

พิมพ์ AT+CWMODE=1   คำสั่งนี้จะเป็นการเลือกโหมดของโมดุล (สามารทำงานได้ 3 โหมด 1 STA , 2 AP และ 3 AP+STA)







การใช้งานโปรแกรม Hello World!


โปรแกรมนี้ จะควมคุมผ่าน ระบบอินทราเน็ต ที่ใช้ WiFi  หรือ วง แลน หรือใช้ เราเตอร์ เดียวกัน เท่านั้น


เราจะเชื่อมต่อ ESP8266 ESP-01 กับเราเตอร์ WiFi โดยใช้  ชื่อ WiFi ที่ต้องการเชื่อมต่อ และรหัสผ่าน ของเครือข่าย

ซึ่ง ESP8266 ESP-01 เมื่อเชื่อมต่อกับ WiFi ของเราแล้ว จะสร้างเว็บเซิร์ฟเวอร์ ซึ่งสามารถ ควบคุมผ่านทาง เว็บเบราเซอร์ ของคอมพิวเตอร์ ที่เชื่อมต่อ WiFi วงเดียวกัน


อัพโหลดโค้ด Arduino เพื่อทดสอบการทำงาน


#include <SoftwareSerial.h>

#define DEBUG true

SoftwareSerial esp8266(2,3); // make RX Arduino line is pin 2, make TX Arduino line is pin 3.
                             // This means that you need to connect the TX line from the esp to the Arduino's pin 2
                             // and the RX line from the esp to the Arduino's pin 3
void setup()
{
  Serial.begin(9600);
  esp8266.begin(9600); // your esp's baud rate might be different
  

  
  sendData("AT+RST\r\n",2000,DEBUG); // reset module
  sendData("AT+CWMODE=2\r\n",1000,DEBUG); // configure as access point
  sendData("AT+CIFSR\r\n",1000,DEBUG); // get ip address
  sendData("AT+CIPMUX=1\r\n",1000,DEBUG); // configure for multiple connections
  sendData("AT+CIPSERVER=1,80\r\n",1000,DEBUG); // turn on server on port 80
}

void loop()
{
  if(esp8266.available()) // check if the esp is sending a message 
  {
    /*
    while(esp8266.available())
    {
      // The esp has data so display its output to the serial window 
      char c = esp8266.read(); // read the next character.
      Serial.write(c);
    } */
    
    if(esp8266.find("+IPD,"))
    {
     delay(1000);

     int connectionId = esp8266.read()-48; // subtract 48 because the read() function returns 
                                           // the ASCII decimal value and 0 (the first decimal number) starts at 48
     
     String webpage = "<h1>Hello</h1>&lth2>World!</h2><button>LED1</button>";

     String cipSend = "AT+CIPSEND=";
     cipSend += connectionId;
     cipSend += ",";
     cipSend +=webpage.length();
     cipSend +="\r\n";
     
     sendData(cipsend,1000,DEBUG);
     sendData(webpage,1000,DEBUG);
     
     webpage="<button>LED2</button>";
     
     cipSend = "AT+CIPSEND=";
     cipSend += connectionId;
     cipSend += ",";
     cipSend +=webpage.length();
     cipSend +="\r\n";
     
     sendData(cipsend,1000,DEBUG);
     sendData(webpage,1000,DEBUG);

     String closeCommand = "AT+CIPCLOSE="; 
     closeCommand+=connectionId; // append connection id
     closeCommand+="\r\n";
     
     sendData(closeCommand,3000,DEBUG);
    }
  }
}


String sendData(String command, const int timeout, boolean debug)
{
    String response = "";
    
    esp8266.print(command); // send the read character to the esp8266
    
    long int time = millis();
    
    while( (time+timeout) > millis())
    {
      while(esp8266.available())
      {
        
        // The esp has data so display its output to the serial window 
        char c = esp8266.read(); // read the next character.
        response+=c;
      }  
    }
    
    if(debug)
    {
      Serial.print(response);
    }
    
    return response;
}



เริ่มการทดสอบ


พิมพ์ AT+RST เป็นการ // Restart โมดุล  จะ return “ready” กลับมาพร้อมทำงานแล้ว


คำสั่งสำหรับการเชื่อมต่อเข้า Router

AT+CWLAP
  // ค้นหา wifi เราเตอร์ ที่เปิดใช้งานอยู่

AT+CWJAP=“ssid”, “password”   //  เชื่อมต่อเข้ากับ เราเตอร์ ต้องมี เครื่องหมาย “‘ ด้วย

ssid = ชื่อ wifi ที่ต้องการเชื่อมต่อ

password =  รหัสผ่าน


AT+CWJAP?    // เช็คว่าเชื่อมต่อได้หรือไม่

...........................................................


ถ้าเชื่อมต่อสำเร็จ



พิมพ์ AT+CWMODE=2 // โหมด 2 AP


พิมพ์  AT+CIFSR // ตรวจสอบไอพี

ถ้าพิมพ์ คำสั่งถูก และ เชื่อมต่อเข้ากับ Router ได้อย่างไม่มีปัญหา ตัว Router จะแจกไอพี มาให้เรา


พิมพ์ AT+CIPMUX=1  // เปิดโหมดการเชื่อมต่อแบบหลายจุด

พิมพ์  AT+CIPSERVER=1,80 //กำหนด TCP server เป็น Port 80





โปรแกรมเขียนเว็บ KompoZer

โปรแกรม KompoZer เป็น โปรแกรมสร้างเว็บ (โปรแกรมเขียนเว็บ) สำหรับคนอยาก ทำเว็บ เองสนับสนุน HTML CSS เหมือน Dreamwaver แต่เร็วกว่าเยอะ ขนาดเล็ก แจกฟรี อีกด้วย

 โปรแกรม KompoZer นี้จัดได้ว่าเป็นการใช้โปรแกรมประเภทเว็บเอดิเตอร์ชนิดหนึ่งที่ใช้ในการสร้าง
เว็บเพจ แต่ข้อดีที่ทำให้โปรแกรมนี้โดดเด่นกว่าโปรแกรมอื่น ๆ ก็คือ เป็นโปรแกรมที่ไม่มีลิขสิทธิ์สามารถนำไปใช้ในการสร้างเว็บเพจเผยแพร่ข้อมูลผ่านระบบอินเตอร์เน็ตได้ ผู้ใช้สามารถเลือกใช้แถบเครื่องมือต่าง ๆคล้ายกับการปรับแต่งเอกสารในโปรแกรมประมวลผลคำ รวมทั้งสามารถจัดการกับเว็บเพจตามโหมดของการแสดงผลที่เลือกได้ตามความต้องการ


ดาวน์โหลดโปรแกรม KompoZer


http://kompozer.net/download.php



 การติดตั้งเหมือนโปรแกรมทั่วๆไป


หน้าตาของ KompoZer




ทดลอง สร้างเพจใหม่โดยไปที่ New -> Page in New Tap




จะมีเพจใหม่เพิ่มเข้ามา



ด้านล่างของเพจซ้ายมือคลิกที่ Source
 

จะแสดง ซอสโค้ด




ก๊อปซอสโค้ด ด้านล่าง (ส่วนที่เป็นสีน้ำเงิน)


<html>
<head>
<title>ESP8266 LED Control</title>
</head>
<body>

<!-- in the <button> tags below the ID attribute is the value sent to the arduino -->

<button id="11" class="led">Toggle Pin 11</button> <!-- button for pin 11 -->
<button id="12" class="led">Toggle Pin 12</button> <!-- button for pin 12 -->
<button id="13" class="led">Toggle Pin 13</button> <!-- button for pin 13 -->

<script src="jquery.min.js"></script>
<script type="text/javascript">
$(document).ready(function(){
$(".led").click(function(){
var p = $(this).attr('id'); // get id value (i.e. pin13, pin12, or pin11)
// send HTTP GET request to the IP address with the parameter "pin" and value "p", then execute the function
$.get("http://192.168.4.1:80/", {pin:p}); // execute get request
});
});
</script>
</body>
</html>



ไปใส่แทนโค้ดเดิม





เลือกที่เก็บไฟล์ และ ตั้งชื่อเพจ index แล้วคลิกที่ Save




คลิกที่ Browse เพื่อดูเพจที่เราสร้างขึ้น




บราวเซอร์ จะแสดงเพจที่เราสร้างขึ้น



เพิ่มเติม . การสร้างไฟล์ /jquery.min.js


โดยไปที่

http://ajax.googleapis.com/ajax/libs/jquery/2.1.3/jquery.min.js






คลิกขวาที่พื้นที่เพจ แล้วเลือกที่ Save as...
 




เลือกที่เก็บเดียวกับเพจ index.html ที่เราสร้างขึ้น แล้วคลิกที่ Save





โปรเจค หุ่นยนต์เดินตามผนัง Wall Arduino



โปรเจค หุ่นยนต์เดินตามผนัง Wall Arduino 
อุปกรณ์ที่ต้องใช้ก็คือ

     1. 4WD Smart Robot Car Chassis Kits

     2. Arduino UNO R3 - Made in italy

     3. Arduino Sensor Shield V5.0

     4. เซนเซอร์ Ultrasonic Module HC-SR04 จำนวน 2 ชิ้น

     5. Mounting Bracket for HC-SR04 Ultrasonic Module แบบสั้น จำนวน 2 ชิ้น

     6. Motor Drive Module L298N

     7. สาย Jumper Female to Male ยาว 20cm.

     8. สาย Jumper Female to Female ยาว 20cm.

     9. รางถ่านแบบ 18650 ใส่ถ่าน 2 ก้อน

     10. แบตเตอรี่ลิเธียม 18650 จำนวน 2 ก้อน

     11. เสารองแผ่นพีซีบีโลหะแบบเหลี่ยม 6 mm

     12. สกรูหัวกลมน็อตตัวเมีย ขนาด 3มม ยาว12มม.

     13. เพาเวอร์สวิตซ์สำหรับเปิดปิด (ON / OFF Rocker Switch)

     14. สายไฟแดงดำ ขนาด 22AWG

เริ่มด้วย ต่อสายไฟสำหรับมอเตอร์ ทั้ง 4 ตัว ที่ 4WD smart car chassis ให้มา โดยให้ ขั้วลบ สายไฟสีดำ อยู่ด้านบน เหมือนกันทั้ง 4 ตัว


ประกอบเข้ากับ โครง ชิ้นที่ 1 ของ 4WD smart car chassis ดังรูป



ประกอบ น็อต 6 จุด สำหรับ วาง โครง ชิ้นที่ 2


ประกอบ บอร์ด Motor Drive Module L298N ลงที่ โครง ชิ้นที่ 1


เชื่อมสายไฟ ของ มอเตอร์ ด้านบน สายสีดำ ขั้ว -  ของมอเตอร์ ตัวที่1 เข้า กับมอเตอร์ ตัวที่2 และ สายสีแดง ขั้ว+  ของมอเตอร์ ตัวที่1 เข้า กับมอเตอร์ ตัวที่2 และ เช่นกันทำที่ มอเตอร์ คู่ด้านล่างด้วย เพื่อให้เหมือนมีมอเตอร์ จาก 4 ตัว เหลือ 2 ตัว

จากนั้น ประกอบสายไฟ ของมอเตอร์ ทั้ง 2 ตัว เข้ากับ บอร์ด L298N ดังรูป



ประกอบ โครงชิ้นที่ 2 เข้าที่ ด้านบนของ โครงชิ้นที่ 1 และ ประกอบ บอร์ด Arduino UNO R3 ลงที่โครงชิ้นที่ 2 ซึ่งอยู่ชั้นบน


ประกอบ บอร์ด Arduino Sensor Shield V5.0 ลงที่ บอร์ด Arduino UNO R3



ประกอบ รางถ่านแบบ 18650 และ เชื่อมต่อ วงจรตามรูป



หมายเหตุ : ถ้ามี Jumper อยู่ที่ขา ENA และ ENB ของ บอร์ด L298N  ให้ถอดออก



การเชื่อมต่อระหว่าง บอร์ด Arduino Sensor Shield V5.0 กับ บอร์ด L298N  



.*** VCC ของ Arduino Sensor Shield V5.0  คือ V ***


หลังจากนั้นให้ทดสอบเบื้องต้น ว่าการหมุนของล้อถูกต้องหรือไม่ โดย

เปิดโปรแกรม Arduino (IDE) และ Upload โค้ดนี้ ไปยัง บอร์ด Arduino UNO R3



// Motor A pins (enableA = enable motor, pinA1 = forward, pinA2 = backward)
int enableA = 3;
int pinA1 = 6;
int pinA2 = 7;

//Motor B pins (enabledB = enable motor, pinB2 = forward, pinB2 = backward)
int enableB = 5;
int pinB1 = 8;
int pinB2 = 9;

//This lets you run the loop a single time for testing
boolean run = true;

void setup() {
 pinMode(enableA, OUTPUT);
 pinMode(pinA1, OUTPUT);
 pinMode(pinA2, OUTPUT);

 pinMode(enableB, OUTPUT);
 pinMode(pinB1, OUTPUT);
 pinMode(pinB2, OUTPUT);
}
void loop() {
  if (run) {
    delay(2000);
    enableMotors();
    //Go forward
    forward(200);
    //Go backward
    backward(200);
    //Turn left
    turnLeft(400);
    coast(200);
    //Turn right
    turnRight(400);
    coast(200);
    //This stops the loop
    run = false; 
  }
}

//Define high-level H-bridge commands

void enableMotors()
{
 motorAOn();
 motorBOn();
}

void disableMotors()
{
 motorAOff();
 motorBOff();
}

void forward(int time)
{
 motorAForward();
 motorBForward();
 delay(time);
}

void backward(int time)
{
 motorABackward();
 motorBBackward();
 delay(time);
}

void turnLeft(int time)
{
 motorABackward();
 motorBForward();
 delay(time);
}

void turnRight(int time)
{
 motorAForward();
 motorBBackward();
 delay(time);
}

void coast(int time)
{
 motorACoast();
 motorBCoast();
 delay(time);
}

void brake(int time)
{
 motorABrake();
 motorBBrake();
 delay(time);
}
//Define low-level H-bridge commands

//enable motors
void motorAOn()
{
 digitalWrite(enableA, HIGH);
}

void motorBOn()
{
 digitalWrite(enableB, HIGH);
}

 //disable motors
void motorAOff()
{
 digitalWrite(enableB, LOW);
}

void motorBOff()
{
 digitalWrite(enableA, LOW);
}

 //motor A controls
void motorAForward()
{
 digitalWrite(pinA1, HIGH);
 digitalWrite(pinA2, LOW);
}

void motorABackward()
{
 digitalWrite(pinA1, LOW);
 digitalWrite(pinA2, HIGH);
}

//motor B controls
void motorBForward()
{
 digitalWrite(pinB1, HIGH);
 digitalWrite(pinB2, LOW);
}

void motorBBackward()
{
 digitalWrite(pinB1, LOW);
 digitalWrite(pinB2, HIGH);
}

//coasting and braking
void motorACoast()
{
 digitalWrite(pinA1, LOW);
 digitalWrite(pinA2, LOW);
}

void motorABrake()
{
 digitalWrite(pinA1, HIGH);
 digitalWrite(pinA2, HIGH);
}

void motorBCoast()
{
 digitalWrite(pinB1, LOW);
 digitalWrite(pinB2, LOW);
}

void motorBBrake()
{
 digitalWrite(pinB1, HIGH);
 digitalWrite(pinB2, HIGH);
}

ถอดสาย USB ระหว่าง Arduino กับ คอมพิวเตอร์ออก และ หาอุปกรณ์ที่สามารถยกตัวรถ 4WD smart car chassis ขึ้นแล้ว ล้อไม่แตะพื้น เพือทดสอบการหมุนของล้อว่าถูกต้องหรือไม่



ใส่ แบตเตอรี่ลิเธียม 18650 จำนวน 2 ก้อน ไปที่ รางถ่าน และ ตรวจสอบขั้วของแบตเตอรี่ ใส่ถุกต้องหรือไม่



โปรแกรมนี้จะทำงานเพียง 1 ครั้ง ถ้าต้องการทดลองใหม่ให้ถอด แบตเตอรี่ออก (หรือ ปิดเปิด สวิทช์ไฟใหม่) แล้วใส่เข้าไปใหม่ เมื่อล้อหมุน ตรวจสอบการหมุน ขอล้อต่างๆถูกต้องหรือไม่ ถ้าต่อวงจรถูกต้อง ล้อ ทั้งสองข้างจะหมุนไปข้างหน้า 1ครั้ง กลับหลัง 1 ครั้ง และ เดินหน้าอีกหนึ่งครั้งแล้วจึงหยุด ถ้าไม่ถูกต้องให้แก้ไข เช่นการต่อขั้วของมอเตอร์ผิด เป็นต้น

ถ้าทุกอย่างถูกต้อง ทดลอง ยกลงวางที่พื้นแล้วทดสอบ อีกครั้ง ถอด แบตเตอรี่ออก (หรือ ปิดเปิด สวิทช์ไฟใหม่) แล้วใส่เข้าไปใหม่ ถ้าทุกอย่างถูกต้อง รถจะเคลื่อนไปข้างหน้า-ถอยหลัง แล้ว เลี้ยวซ้าย แล้ว จึงเลี้ยวขวากลับสู่ตำแหน่งเดิม


เชื่อมต่อ เซ็นเซอร์ HC-SR04  ตัวที่ 1 กับ Sensor Shield V5.0 ดังรูป



ประกอบ HC-SR04 ตัวที่1  เข้ากับ Mounting Bracket for HC-SR04 Ultrasonic Module แบบสั้น และ ประกอบ Bracket  เข้ากลับ โครงรถ ตามรูป



NewPing.h  คือลบรารี่ NewPing เป็น ไลบรารี่ ฟังก์ชัน ที่มีผู้พัฒนาเตรียมพร้อมไว้ให้เราแล้ว โดยให้ไปดาวน์โหลด ไลบรารี่ NewPing ได้ที่

 ตัวอย่างการใช้งาน ตามลิงค์ด้านล่าง

https://robotsiam.blogspot.com/2016/09/ultrasonic-module-hc-sr04.html




และทดสอบการเชื่อมต่อ HC-SR04  ตัวที่ 1 ว่าถูกต้องหรือไม่ อุปกรณ์ใช้งานได้หรือไม่ โดย Upload โค้ดนี้ ไปยัง บอร์ด Arduino UNO R3


#include <NewPing.h>

NewPing sonar(10, 11);  //ให้ Pin 10 และ 11 เป็นขาของเซนเซอร์ เรียกใช้งานคำสั่งจาก Library

long cm;  //ประกาศตัวแปร cm ให้เป็นข้อมูลชนิดจำนวนเต็ม -2147483648 ถึง 2147483649

void setup()

{
 
Serial.begin(9600); //ตั้งค่าความเร็วในการรับ-ส่งข้อมูล ค่ามาตรฐาน คือ 9600

}

void loop()

{
 
delay(50);
cm = sonar.ping_cm(); //รับค่าจาก Library NewPing หน่วยเป็น เซ็นติเมตร
Serial.print(cm);  //พิมพ์ค่าที่ได้ออกมา
Serial.print(" cm."); //พิมพ์ cm ต่อท้าย ค่าที่ได้รับ
Serial.print("\n"); 

}



เมื่อ Upload เสร็จ ให้เปิด Serial Monitor ขึ้นมา โดยไปที่  Tools -> Serial Monitor



ทดลอง เอามือ หรือ วัตถุอื่นๆ เครื่อนไหว ขึ้นลง หน้าจุดรับสัญญาณ อัลตร้าโซนิค HC-SR04

ที่ Serial Monitor จะแสดงค่า ระยะความห่างของมือเรากับ HC-SR04 หน่วยเป็น เซ็นติเมตร (cm) ตามที่เราเครื่อนไหว แสดงว่า โมดูลอัลตร้าโซนิค HC-SR04 ของเรา นั้นพร้อมใช้งานแล้วครับ


เชื่อมต่อ เซ็นเซอร์ HC-SR04  ตัวที่ 2 กับ Sensor Shield V5.0


Sensor Shield V5.0 <--> HC-SR04 ตัวที่2

V <--> VCC
G <--> GND
D12  <--> Trig
D13  <--> Echo


ประกอบ HC-SR04 ตัวที่2  เข้ากับ Mounting Bracket for HC-SR04 Ultrasonic Module แบบสั้น และ ประกอบ Bracket  เข้ากลับ โครงรถ ตามรูป






และทดสอบการเชื่อมต่อ HC-SR04  ตัวที่ 2 ว่าถูกต้องหรือไม่ อุปกรณ์ใช้งานได้หรือไม่ โดย Upload โค้ดนี้ ไปยัง บอร์ด Arduino UNO R3


#include <NewPing.h>

NewPing sonar(12, 13);  //ให้ Pin 12 และ 13 เป็นขาของเซนเซอร์ เรียกใช้งานคำสั่งจาก Library

long cm;  //ประกาศตัวแปร cm ให้เป็นข้อมูลชนิดจำนวนเต็ม -2147483648 ถึง 2147483649

void setup()

{
 
Serial.begin(9600); //ตั้งค่าความเร็วในการรับ-ส่งข้อมูล ค่ามาตรฐาน คือ 9600

}

void loop()

{
 
delay(50);
cm = sonar.ping_cm(); //รับค่าจาก Library NewPing หน่วยเป็น เซ็นติเมตร
Serial.print(cm);  //พิมพ์ค่าที่ได้ออกมา
Serial.print(" cm."); //พิมพ์ cm ต่อท้าย ค่าที่ได้รับ
Serial.print("\n"); 

}



และ ทดสอบการทำงาน โดยทำตามขั้นตอนเหมือน  HC-SR04  ตัวที่ 1




แนวคิด การทำงาน ของ หุ่นยนต์เดินตามผนัง Wall Arduino คือ หุ่นยนต์จะเดินห่างผนังไม่เกิน 15 เซ็นติเมตร และ เมื่อเจอผนังด้านหน้า 
ให้เลี้ยวซ้าย


เขียนตัวอย่างโค้ดได้ดังนี้




 if ((sensor_1 < 10) && (sensor_2 > 15)) {

    turnLeft(100);
    forward(1);

  }

  else if  ((sensor_1 > 15) && (sensor_2 > 15)) {

    turnRight(100);
    forward(1);
  }

  else if  ((sensor_1 > 10) && (sensor_1 < 15) && (sensor_2 > 15)) {

    forward(1);
  }
 
else if  ((sensor_1 > 10) && (sensor_1 < 15) && (sensor_2 < 15)) {


    turnLeft(600);
    forward(1);

  }
 
else   {


    forward(1);

  }

}

1. เมื่อเซ็นเซอร์ 
HC-SR04  ตัวที่ 1 (ด้านข้าง) ตรวจจับ ค่าความห่างจากผนัง น้อยกว่า 10 เซ็นติเมตร และ เซ็นเซอร์ HC-SR04  ตัวที่ 2 (ด้านหน้า) อยู่ห่างจากผนัง น้อยกว่า 15 เซ็นติเมตร  ให้หุ่นยนต์เลี้ยวไปทางซ้าย แล้วจึงเดินหน้า



2. เมื่อเซ็นเซอร์ HC-SR04  ตัวที่ 1 (ด้านข้าง) ตรวจจับ ค่าความห่างจากผนัง มากกว่า 15 เซ็นติเมตร และ เซ็นเซอร์ HC-SR04  ตัวที่ 2 (ด้านหน้า) อยู่ห่างจากผนัง น้อยกว่า 15 เซ็นติเมตร  ให้หุ่นยนต์เลี้ยวไปทางขวา แล้วจึงเดินหน้า



3. เมื่อเซ็นเซอร์ HC-SR04  ตัวที่ 1 (ด้านข้าง) ตรวจจับ ค่าความห่างจากผนัง มากกว่า 10 เซ็นติเมตร และ น้อยกว่า 15 เซ็นติเมตร  และ เซ็นเซอร์ HC-SR04  ตัวที่ 2 (ด้านหน้า) อยู่ห่างจากผนัง มากกว่า 15 เซ็นติเมตร  ให้หุ่นยนต์เดินหน้า



4. เมื่อเซ็นเซอร์ HC-SR04  ตัวที่ 1 (ด้านข้าง) ตรวจจับ ค่าความห่างจากผนัง มากกว่า 10 เซ็นติเมตร และ น้อยกว่า 15 เซ็นติเมตร  และ เซ็นเซอร์ HC-SR04  ตัวที่ 2 (ด้านหน้า) อยู่ห่างจากผนัง น้อยกว่า 15 เซ็นติเมตร  ให้หุ่นยนต์เลี้ยวซ้าย 90 องศา แล้วจึงเดินหน้า




5. อื่นๆ
  ให้หุ่นยนต์เดินหน้า



6.ภาพรวมการทำงาน





จากนั้น Upload โค้ดโปรเจค หุ่นยนต์เดินตามผนัง Wall Arduino  ไปยัง บอร์ด Arduino UNO R3




#include <NewPing.h>

//Tell the Arduino where the sensor is hooked up
NewPing sonar1(10, 11);
NewPing sonar2(12, 13);

int enableA = 3;
int pinA1 = 6;
int pinA2 = 7;

int enableB = 5;
int pinB1 = 8;
int pinB2 = 9;

long sensor_1;
long sensor_2;

void setup() {
  pinMode(enableA, OUTPUT);
  pinMode(pinA1, OUTPUT);
  pinMode(pinA2, OUTPUT);

  pinMode(enableB, OUTPUT);
  pinMode(pinB1, OUTPUT);
  pinMode(pinB2, OUTPUT);

  delay(2000);
}

void loop() {

  //Run the motors at slightly less than full power
  analogWrite(enableA, 200);   // ปรับค่าความเร็วของหุ่นยนต์ 0-255
  analogWrite(enableB, 200);   // ปรับค่าความเร็วของหุ่นยนต์ 0-255

  //Ping the sensor and determine the distance in inches
  sensor_1 = sonar1.ping_cm(); // ค่าเซ็นเซอร์ตัวที่ 1 ความห่างหน่วยเป็นเซ็นติเมตร
  sensor_2 = sonar2.ping_cm(); // ค่าเซ็นเซอร์ตัวที่ 2 ความห่างหน่วยเป็นเซ็นติเมตร

  //If the robot detects an obstacle less than four inches away, it will back up, then turn left; if no obstacle is detected, it will go forward
  if ((sensor_1 < 10) && (sensor_2 > 15)) {

    turnLeft(100);
    forward(1);

  }

  else if  ((sensor_1 > 15) && (sensor_2 > 15)) {

    turnRight(100);
    forward(1);
  }

  else if  ((sensor_1 > 10) && (sensor_1 < 15) && (sensor_2 > 15)) {

    forward(1);
  }
  else if  ((sensor_1 > 10) && (sensor_1 < 15) && (sensor_2 < 15)) {

    turnLeft(600);
    forward(1);

  }
  else   {

    forward(1);

  }

}

//Define high-level H-bridge commands

void enableMotors()
{
  motorAOn();
  motorBOn();
}

void disableMotors()
{
  motorAOff();
  motorBOff();
}

void forward(int time)
{
  motorAForward();
  motorBForward();
  delay(time);
}

void backward(int time)
{
  motorABackward();
  motorBBackward();
  delay(time);
}

void turnLeft(int time)
{
  motorABackward();
  motorBForward();
  delay(time);
}

void turnRight(int time)
{
  motorAForward();
  motorBBackward();
  delay(time);
}

void coast(int time)
{
  motorACoast();
  motorBCoast();
  delay(time);
}

void brake(int time)
{
  motorABrake();
  motorBBrake();
  delay(time);
}
//Define low-level H-bridge commands

//enable motors
void motorAOn()
{
  digitalWrite(enableA, HIGH);
}

void motorBOn()
{
  digitalWrite(enableB, HIGH);
}

//disable motors
void motorAOff()
{
  digitalWrite(enableB, LOW);
}

void motorBOff()
{
  digitalWrite(enableA, LOW);
}

//motor A controls
void motorAForward()
{
  digitalWrite(pinA1, HIGH);
  digitalWrite(pinA2, LOW);
}

void motorABackward()
{
  digitalWrite(pinA1, LOW);
  digitalWrite(pinA2, HIGH);
}

//motor B controls
void motorBForward()
{
  digitalWrite(pinB1, HIGH);
  digitalWrite(pinB2, LOW);
}

void motorBBackward()
{
  digitalWrite(pinB1, LOW);
  digitalWrite(pinB2, HIGH);
}

//coasting and braking
void motorACoast()
{
  digitalWrite(pinA1, LOW);
  digitalWrite(pinA2, LOW);
}

void motorABrake()
{
  digitalWrite(pinA1, HIGH);
  digitalWrite(pinA2, HIGH);
}

void motorBCoast()
{
  digitalWrite(pinB1, LOW);
  digitalWrite(pinB2, LOW);
}

void motorBBrake()
{
  digitalWrite(pinB1, HIGH);
  digitalWrite(pinB2, HIGH);

}






ภาพรวมการต่อ หุ่นยนต์เดินตามผนัง Wall Arduino




วีดีโอผลลัพธ์การทำงานของ โปรเจค หุ่นยนต์เดินตามผนัง Wall Arduino